AS3: Motion Blurring with Flash, part 2

package {
	//Basic classes
	import flash.events.MouseEvent;
	import flash.display.MovieClip;
	import flash.events.Event;
	//
 
	//Filter class, specifically for the Blur
	import flash.filters.BitmapFilterQuality;
	import flash.filters.BlurFilter;
	//
 
	//Transition class for the tween easing setting of Strong
	import fl.transitions.easing.Strong;
	//	
 
	//Transition class needed for the Tween
	import fl.transitions.*;
	//
 
	public class FilterBlur extends MovieClip {
 
		//Private variables
		private var tweenWidth : Tween;
		private var tweenHeight : Tween;
		private var tweenXLoc : Tween;
		private var tweenYLoc : Tween;
		private var xBlurOn : Number = 50;
		private var yBlurOn : Number = 50;
		private var tweenState : int = 0;
		private var tweenStateCount:int = 4;
 
		//Public variables
		public var stageWidth : Number = stage.stageWidth;
		public var stageHeight : Number = stage.stageHeight;
		public var thisWidth : Number = 100;
		public var thisHeight : Number = 75;
		public var thisXLoc : Number = (stageWidth / 2) - (thisWidth / 2);
		public var thisYLoc : Number = (stageHeight / 2) - (thisHeight / 2);
 
		//Constructor
		public function FilterBlur() {
			//I like to set this in the beginning so the Flash player is not constantly trying to locate it
			this.width = thisWidth;
			this.height = thisHeight;
			this.x = thisXLoc;
			this.y = thisYLoc;
 
			//Main listener to handle the MOUSE_DOWN on the movieclip instance
			this.addEventListener(MouseEvent.MOUSE_DOWN, blurInitiate);
		}
 
		//Handle the tween logic
		public function blurInitiate(e : MouseEvent) : void {
			//Reset the tweenState count each call
			tweenState = 0;
 
			//Turn the blur effect on
			blurON(null);
 
			//Constantly watch the tweenState count to turn off the blur
			this.addEventListener(Event.ENTER_FRAME, watchBlur);
 
			//Width and Height
			tweenWidth = new Tween(this, "width", Strong.easeIn, thisWidth * 2, thisWidth, 1, true);
			tweenWidth.addEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
			tweenHeight = new Tween(this, "height", Strong.easeIn, thisHeight * 2, thisHeight, 1, true);
			tweenHeight.addEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
 
			//X and Y
			tweenXLoc = new Tween(this, "x", Strong.easeIn, thisXLoc - (thisWidth / 2), thisXLoc, 1, true);
			tweenXLoc.addEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
			tweenYLoc = new Tween(this, "y", Strong.easeIn, thisYLoc - (thisHeight / 2), thisYLoc, 1, true);
			tweenYLoc.addEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
 
			/*
			Increment the tweenState count. I do this as there are FOUR tweens going on at one time and
			I want to make sure all FOUR tweens are completed before moving on. This ensures that each tween
			has ended before the blurOFF function is called.
			 */
			function aggregateTweens(e : TweenEvent) : int {
				switch (e.currentTarget) {
					case tweenWidth:
						tweenWidth.removeEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
						return tweenState += 1;
						break;
 
					case tweenHeight:
						tweenHeight.removeEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
						return tweenState += 1;
						break;
 
					case tweenXLoc:
						tweenXLoc.removeEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
						return tweenState += 1;
						break;
 
					case tweenYLoc:
						tweenYLoc.removeEventListener(TweenEvent.MOTION_FINISH, aggregateTweens);
						return tweenState += 1;
						break;		
 
					default:
						tweenState = 0;
				}
 
				return tweenState;
			}
		}
 
		//Watch for state count to turn blur off / We could throw events to access this, but an int increment is simpler here.
		public function watchBlur(e : Event) : void {
			if(tweenState == tweenStateCount) {
				//If the count is equal to 4 or the total tweens the call the blurOFF function.
				blurOFF(null);
				//Clean up the ENTER_FRAME event listener
				this.removeEventListener(Event.ENTER_FRAME, watchBlur);
			}
		}
 
		//Set the blur filter ON
		public function blurON(e : Event) : void {
			var blur : BlurFilter = new BlurFilter();
			blur.blurX = xBlurOn;
			blur.blurY = yBlurOn;
			blur.quality = BitmapFilterQuality.MEDIUM;
			this.filters = [blur];
		}
 
		//Set the blur filter OFF
		public function blurOFF(e : Event) : void {
			var blur : BlurFilter = new BlurFilter();
			blur.blurX = 0;
			blur.blurY = 0;
			blur.quality = BitmapFilterQuality.MEDIUM;
			this.filters = [blur];
		}
	}
}